AW·Soft: Power Builder Tips & How To

ENG

RUS

MOST POPULAR

Notify for Notes

Home Page

MY SOFTWARE & SCRIPTS

Notify for Notes

Compare SQL

Other Scripts

ARTICLES & FORUM

Mobile Software

Internet Software

Forum

TIPS, TRICKS & HOW TO

Power Builder

Lotus Notes

Miscellaneous

POWER BUILDER TIPS & HOW TO

• Here I've been collecting the simple solutions under Power Builder environmental scripts and controls. Take a glance at these questions and answers. May be it will be useful for you...

Note: You can learn more about PowerBuilder at Sybase WEB Site.

» Send keyboard events into any valid window

At first declare a function as global or local external. After that call it twice under event script in your control receiving the keys:

// External Function Declaration
Subroutine keybd_event (int bVk, int bScan, int dwFlags, int dwExtraInfo) Library 'user32'

    // Script
Constant Long VK_TAB = 9
Constant Long VK_ESCAPE = 27
...

keybd_event(VK_TAB,0,0,0)        //Depress Tab
keybd_event(VK_TAB,0,2,0)        //Release Tab

To learn values of VK_* constants see MSDN Documentation.

» Working with ports (COM, LPT, etc.) under Power Builder

Example	Size
Non-Visual Port Example (Source)	2,051

At first declare some functions as global or local external and appropriate structures in newly created non-visual object.

// External Function Declaration

Function long CreateFile(string lpszName, long fdwAccess, long fdwShareMode, long lpsa, long fdwCreate, long fdwAttrsAndFlags, long hTemplateFile ) Library "KERNEL32" Alias For CreateFileA
Function boolean ReadFile(long hFile, ref char lpBuffer[], long nNumberOfBytesToWrite, ref long lpNumberOfBytesWritten, long lpOverlapped ) Library "KERNEL32"
Function boolean WriteFile(long hFile, ref char lpBuffer[], long nNumberOfBytesToWrite, ref long lpNumberOfBytesWritten, long lpOverlapped ) Library "KERNEL32"
Function boolean CloseHandle(long hObject ) Library "KERNEL32"

Function boolean SetCommState(long hFile, ref st_dcb lpDCB) Library "KERNEL32"
Function boolean GetCommState(long hFile, ref st_dcb lpDCB) Library "KERNEL32"
Function boolean SetCommTimeouts(long hFile, ref st_commtimeouts lpCommTimeouts) Library "KERNEL32"
Function boolean GetCommTimeouts(long hFile, ref st_commtimeouts lpCommTimeouts) Library "KERNEL32"
Function boolean SetupComm(long hFile, long dwInQueue, long dwOutQueue) Library "KERNEL32"

Subroutine Sleep(long dwMilliseconds) Library "KERNEL32"
Function long GetLastError() Library "KERNEL32"

    // Declaration of Related Structures
type st_commtimeouts from structure
   unsignedlong readintervaltimeout
   unsignedlong readtotaltimeoutmultiplier
   unsignedlong readtotaltimeoutconstant
   unsignedlong writetotaltimeoutmultiplier
   unsignedlong writetotaltimeoutconstant
end type

type st_dcb from structure
   unsignedlong dcblength
   unsignedlong baudrate
   unsignedlong fdummy2
   integer wreserved
   integer xonlim
   integer xofflim
   character bytesize
   character parity
   character stopbits
   character xonchar
   character xoffchar
   character errorchar
   character eofchar
   character evtchar
   integer wreserved1
end type

// Declaration of Instance Variables
st_dcb lpDCB
st_commtimeouts lpCTO
Long Handle = 0

Next we're going to create high-level functions to work with. This three functions (uf_openport(), uf_writeport(), uf_closeport()) have all to deal with ports:

    // Function Examples

function boolean uf_openport (string as_portname);
Long lNull
Long ll_written
String ls_send, ls_property
Constant ULong GENERIC_READ = 2147483648 // (0x80000000L)
Constant ULong GENERIC_WRITE = 1073741824 // (0x40000000L)
Constant ULong OPEN_EXISTING = 3

SetNull(lNull)

   // open the port by creating the file
Handle = CreateFile(as_portname, GENERIC_READ + GENERIC_WRITE, 0, lNull, OPEN_EXISTING, 0, lNull)

If Handle >= 0 Then
    If GetCommState(Handle, lpDCB) Then
            //BaudRate - 2400,4800,9600,19400,etc.
        lpDCB.BaudRate = Long(9600)
            //ByteSize(Data Bits) - 4,5,6,7,8
        lpDCB.ByteSize = Char(8)
            //Parity - 0=None;1=Odd;2=Even;3=Mark;4=Space
        lpDCB.Parity = Char(0)
            //StopBits - 0=1;1=1.5;2=2
        lpDCB.StopBits = Char(0)

        If Not SetCommState(Handle, lpDCB) Then
            CloseHandle(Handle)
            RETURN FALSE
        End If
    Else
        CloseHandle(Handle)
        RETURN FALSE
    End If

    If GetCommTimeouts(Handle, lpCTO) Then
            //Set up following variables to values you want
        lpCTO.ReadIntervalTimeout = Long(50)
        lpCTO.ReadTotalTimeoutMultiplier = Long(0)
        lpCTO.ReadTotalTimeoutConstant = Long(1000)
        lpCTO.WriteTotalTimeoutMultiplier = Long(0)
        lpCTO.WriteTotalTimeoutConstant = Long(0)

        If Not SetCommTimeouts(Handle, lpCTO) Then
            CloseHandle(Handle)
            RETURN FALSE
        End If
        SetupComm(Handle, Long(1024), Long(1024))
    Else
        CloseHandle(Handle)
        RETURN FALSE
    End If
Else
    RETURN FALSE
End If

RETURN TRUE
end function

function long uf_writeport (string as_string);
// RETURN VALUES (Example):
// 128 - ERROR
// 131 - SUCCESSFUL
// 100 - PORT DELAY ERROR

Char lch_input[], lch_output[]
Long ll_written = 0, lNull, ll_counter

If Handle <= 0 Then RETURN 100

SetNull(lNull)

ll_counter = Len(as_string)

Do While ll_counter > 0
    lch_input[ll_counter] = Char(Mid(as_string, ll_counter, 1))
    ll_counter --
Loop

Sleep(lpcto.ReadIntervalTimeout)

If Not WriteFile(Handle, lch_input, UpperBound(lch_input), ll_written, lNull) Then
    RETURN 128    // Write to Port Failed
End If

ll_counter = 5 // 5 Timeouts
lch_output[Len(as_string)] = Char(0) // Initialize output

Do
    Sleep(lpcto.ReadIntervalTimeout)
    ReadFile(Handle, lch_output, UpperBound(lch_output), ll_written, lNull)
    ll_counter --
Loop While ll_written = 0 And ll_counter > 0

Sleep(lpcto.ReadIntervalTimeout)

If ll_counter <= 0 Then RETURN 100 // Port not answered

RETURN 131
end function

function boolean uf_closeport ();
    Boolean b_ret

    b_ret = CloseHandle(Handle)
    Handle = 0
    RETURN b_ret
end function

At the end I'll show some lines with code where you could understand the idea:

    // Script

String ls_data = "Hello, the First COM..."
nvo_port COM // Our non-visual object

If COM.uf_OpenPort("COM1") Then
    If COM.uf_writeport(ls_data) <> 131 Then
        ...    // Error Handler
    End If
    COM.uf_ClosePort()
End If

Get the source of example and import it into your project. I hope these pieses of code will help you.

» How show tooltips under ListView control (ListViewReport! style) in case of long descriptions

It's extremely simple. Add this string into ListView Constructor! script:

// Tooltips
Send(Handle(This), 4096 + 54, 1024, 1024)

» The Fast Boolean Assignment

Any time you're going to assign value to a boolean variable you write something like this:

Boolean lb_test

If ([some expression]) Then
    lb_test = TRUE
Else If ([some expression]) Then
    lb_test = FALSE
Else
    SetNull(lb_test)
End If

I suggest you to try another vivid type of assignment:

Boolean lb_test

lb_test = [some expression] Or/And [some expression]

AD LINKS

COUNTERS

[an error occurred while processing the directive]